USB_Host_Shield_2.0/examples/Xbox/XBOXOLD/XBOXOLD.ino

/*
 Example sketch for the original Xbox library - developed by Kristian Lauszus
 For more information visit my blog: http://blog.tkjelectronics.dk/ or 
 send me an e-mail:  kristianl@tkjelectronics.com
 */

#include <XBOXOLD.h>
#include <usbhub.h>

USB Usb;
USBHub  Hub1(&Usb); // The controller has a built in hub, so this instance is needed
XBOXOLD Xbox(&Usb);

void setup() {
  Serial.begin(115200);
  if (Usb.Init() == -1) {
    Serial.print(F("\r\nOSC did not start"));
    while(1); // halt
  }  
  Serial.print(F("\r\nXBOX Library Started"));
}
void loop() {
  Usb.Task();
  if(Xbox.XboxConnected) {
    if(Xbox.getButtonPress(BLACK) || Xbox.getButtonPress(WHITE)) {
      Serial.print("BLACK: ");
      Serial.print(Xbox.getButtonPress(BLACK));
      Serial.print("\tWHITE: ");
      Serial.println(Xbox.getButtonPress(WHITE));
      Xbox.setRumbleOn(Xbox.getButtonPress(BLACK),Xbox.getButtonPress(WHITE));
    } else
      Xbox.setRumbleOn(0,0);
    if(Xbox.getAnalogHat(LeftHatX) > 7500 || Xbox.getAnalogHat(LeftHatX) < -7500 || Xbox.getAnalogHat(LeftHatY) > 7500 || Xbox.getAnalogHat(LeftHatY) < -7500 || Xbox.getAnalogHat(RightHatX) > 7500 || Xbox.getAnalogHat(RightHatX) < -7500 || Xbox.getAnalogHat(RightHatY) > 7500 || Xbox.getAnalogHat(RightHatY) < -7500) {
      if(Xbox.getAnalogHat(LeftHatX) > 7500 || Xbox.getAnalogHat(LeftHatX) < -7500) {
        Serial.print(F("LeftHatX: ")); 
        Serial.print(Xbox.getAnalogHat(LeftHatX));
        Serial.print("\t");
      } 
      if(Xbox.getAnalogHat(LeftHatY) > 7500 || Xbox.getAnalogHat(LeftHatY) < -7500) {
        Serial.print(F("LeftHatY: ")); 
        Serial.print(Xbox.getAnalogHat(LeftHatY));
        Serial.print("\t");
      } 
      if(Xbox.getAnalogHat(RightHatX) > 7500 || Xbox.getAnalogHat(RightHatX) < -7500) {
        Serial.print(F("RightHatX: ")); 
        Serial.print(Xbox.getAnalogHat(RightHatX));
        Serial.print("\t");      
      } 
      if(Xbox.getAnalogHat(RightHatY) > 7500 || Xbox.getAnalogHat(RightHatY) < -7500) {
        Serial.print(F("RightHatY: ")); 
        Serial.print(Xbox.getAnalogHat(RightHatY));  
      }
      Serial.println();
    }
    
    if(Xbox.getButtonClick(UP))
      Serial.println(F("Up"));
    if(Xbox.getButtonClick(DOWN))
      Serial.println(F("Down"));
    if(Xbox.getButtonClick(LEFT))
      Serial.println(F("Left"));
    if(Xbox.getButtonClick(RIGHT))
      Serial.println(F("Right"));

    if(Xbox.getButtonClick(START))
      Serial.println(F("Start"));
    if(Xbox.getButtonClick(BACK))
      Serial.println(F("Back"));
    if(Xbox.getButtonClick(L3))
      Serial.println(F("L3"));
    if(Xbox.getButtonClick(R3))
      Serial.println(F("R3"));

    if(Xbox.getButtonPress(A)) {
      Serial.print(F("A: "));
      Serial.println(Xbox.getButtonPress(A));
    }
    if(Xbox.getButtonPress(B)) {
      Serial.print(F("B: "));
      Serial.println(Xbox.getButtonPress(B));
    }
    if(Xbox.getButtonPress(X)) {
      Serial.print(F("X: "));
      Serial.println(Xbox.getButtonPress(X));
    }
    if(Xbox.getButtonPress(Y)) {
      Serial.print(F("Y: "));
      Serial.println(Xbox.getButtonPress(Y));
    }
    if(Xbox.getButtonPress(L1)) {
      Serial.print(F("L1: "));
      Serial.println(Xbox.getButtonPress(L1));
    }
    if(Xbox.getButtonPress(R1)) {
      Serial.print(F("R1: "));
      Serial.println(Xbox.getButtonPress(R1));
    }
  }
  delay(1);
}