USB_Host_Shield_2.0/examples/Xbox/XBOXRECV/XBOXRECV.ino

/*
 Example sketch for the Xbox Wireless Reciver library - developed by Kristian Lauszus
 It supports up to four controllers wirelessly
 For more information see the blog post: http://blog.tkjelectronics.dk/2012/12/xbox-360-receiver-added-to-the-usb-host-library/ or 
 send me an e-mail:  kristianl@tkjelectronics.com
 */

#include <XBOXRECV.h>
USB Usb;
XBOXRECV Xbox(&Usb);

void setup() {
  Serial.begin(115200);
  if (Usb.Init() == -1) {
    Serial.print(F("\r\nOSC did not start"));
    while(1); //halt
  }
  Serial.print(F("\r\nXbox Wireless Receiver Library Started"));
}
void loop() {
  Usb.Task();
  if(Xbox.XboxReceiverConnected) {
    for(uint8_t i=0;i<4;i++) {
      if(Xbox.Xbox360Connected[i]) {
        if(Xbox.getButtonPress(L2,i) || Xbox.getButtonPress(R2,i)) {
          Serial.print("L2: ");
          Serial.print(Xbox.getButtonPress(L2,i));
          Serial.print("\tR2: ");
          Serial.println(Xbox.getButtonPress(R2,i));
          Xbox.setRumbleOn(Xbox.getButtonPress(L2,i),Xbox.getButtonPress(R2,i),i);
        }
        if(Xbox.getAnalogHat(LeftHatX,i) > 7500 || Xbox.getAnalogHat(LeftHatX,i) < -7500 || Xbox.getAnalogHat(LeftHatY,i) > 7500 || Xbox.getAnalogHat(LeftHatY,i) < -7500 || Xbox.getAnalogHat(RightHatX,i) > 7500 || Xbox.getAnalogHat(RightHatX,i) < -7500 || Xbox.getAnalogHat(RightHatY,i) > 7500 || Xbox.getAnalogHat(RightHatY,i) < -7500) {
          if(Xbox.getAnalogHat(LeftHatX,i) > 7500 || Xbox.getAnalogHat(LeftHatX,i) < -7500) {
            Serial.print(F("LeftHatX: ")); 
            Serial.print(Xbox.getAnalogHat(LeftHatX,i));
            Serial.print("\t");
          } 
          if(Xbox.getAnalogHat(LeftHatY,i) > 7500 || Xbox.getAnalogHat(LeftHatY,i) < -7500) {
            Serial.print(F("LeftHatY: ")); 
            Serial.print(Xbox.getAnalogHat(LeftHatY,i));
            Serial.print("\t");
          } 
          if(Xbox.getAnalogHat(RightHatX,i) > 7500 || Xbox.getAnalogHat(RightHatX,i) < -7500) {
            Serial.print(F("RightHatX: ")); 
            Serial.print(Xbox.getAnalogHat(RightHatX,i));
            Serial.print("\t");      
          } 
          if(Xbox.getAnalogHat(RightHatY,i) > 7500 || Xbox.getAnalogHat(RightHatY,i) < -7500) {
            Serial.print(F("RightHatY: ")); 
            Serial.print(Xbox.getAnalogHat(RightHatY,i));
          }
          Serial.println();
        }

        if(Xbox.getButtonClick(UP,i)) {
          Xbox.setLedOn(LED1,i);
          Serial.println(F("Up"));
        }      
        if(Xbox.getButtonClick(DOWN,i)) {
          Xbox.setLedOn(LED4,i);
          Serial.println(F("Down"));
        }
        if(Xbox.getButtonClick(LEFT,i)) {
          Xbox.setLedOn(LED3,i);
          Serial.println(F("Left"));
        }
        if(Xbox.getButtonClick(RIGHT,i)) {
          Xbox.setLedOn(LED2,i);
          Serial.println(F("Right"));
        }        

        if(Xbox.getButtonClick(START,i)) {
          Xbox.setLedMode(ALTERNATING,i);
          Serial.println(F("Start"));
        }
        if(Xbox.getButtonClick(BACK,i)) {
          Xbox.setLedBlink(ALL,i);
          Serial.println(F("Back"));
        }
        if(Xbox.getButtonClick(L3,i))
          Serial.println(F("L3"));
        if(Xbox.getButtonClick(R3,i))
          Serial.println(F("R3"));

        if(Xbox.getButtonClick(L1,i))
          Serial.println(F("L1"));
        if(Xbox.getButtonClick(R1,i))
          Serial.println(F("R1"));
        if(Xbox.getButtonClick(XBOX,i)) {
          Xbox.setLedMode(ROTATING,i);
          Serial.print(F("Xbox (Battery: "));
          Serial.print(Xbox.getBatteryLevel(i)); // The battery level in the range 0-3
          Serial.println(F(")"));
        }
        if(Xbox.getButtonClick(SYNC,i))
          Serial.println(F("Sync"));

        if(Xbox.getButtonClick(A,i))
          Serial.println(F("A"));
        if(Xbox.getButtonClick(B,i))
          Serial.println(F("B"));
        if(Xbox.getButtonClick(X,i))
          Serial.println(F("X"));
        if(Xbox.getButtonClick(Y,i))
          Serial.println(F("Y"));
      }
    }
  }  
  delay(1);
}